在Excel 2016中提供了14個IS函數，主要是用于判斷數據類型、錯誤值、奇偶、空白單元格等 。工作中常見的IS函數分類如下：

常見的IS類函數

如下圖，在B13單元格中，使用VLOOKUP函數利用A3單元格的姓名查詢部門名稱。因為在A13單元格中輸入的姓名中間加入了空格，不匹配，從而無法查到對應信息而返回錯誤錯 #N/A的錯誤值。

錯誤值

可使用下列公式将錯誤給屏蔽掉！即始果返回的值為錯誤值，則顯示為空白單元格。

方法一：使用ISERROR函數

在B13單元格中輸入下列公式：

= IF(ISERROR(VLOOKUP($A13,$A$2:$C$9,2,FALSE)),"",VLOOKUP($A13,$A$2:$C$9,2,FALSE))

公式解析如下：

即=IF(ISERROR(原公式,"",原公式)

先使用ISERROR判斷公式VLOOKUP($A13,$A$2:$C$9,2,FALSE)返回的查找結果，如果結果為錯誤值，則ISERROR就會返回邏輯值TRUE。其在公式中作為IF的判斷條件，判斷條件為TRUE，則顯示為空值，否則就正常顯示VLOOKUP公式返回的結果值。

ISERROR函數用法

方法二：使用ISNA函數

在B13單元格中輸入下列公式：

=IF(ISNA(VLOOKUP($A13,$A$2:$C$9,2,FALSE)),"",VLOOKUP($A13,$A$2:$C$9,2,FALSE))

ISNA函數是專門用來判斷“#N/A”類的錯誤值。一般與VLOOKUP和MATCH函數配合使用。比起ISERROR函數來說，可以提高計算速度。

方法三：使用IFERROR或IFNA函數

在office 2007及以後的版本裡，新增加了IFERROR和IFNA函數，進行錯誤值屏蔽時，巧妙地使用此函數，可以大大地減少公式的複雜度，使用方法如下：

IFERROR(原公式，"")

IFNA(原公式,"")

使用此函數，公式可簡化為：

=IFERROR(VLOOKUP($A13,$A$2:$C$8,2,FALSE),"") =IFNA(VLOOKUP($A13,$A$2:$C$9,2,FALSE),"")

在Excel中輸入全數字身份證号碼時，因為Excel最大精确的位數為15位，所以當輸入18位數字時會自動變為科學計數顯示，即使再改變格式為文本，後3位也将變成000，且無法逆轉。因此，必須先設置單元格格式為“文本”類型，以文本存儲18位身份證号碼。

另外，現在18位身份證号碼，有的是18位數字，有的是17位數字加一位檢驗碼"X"。為了防止在錄入時出錯，可以先設置單元格的數據有效性進行限制，操作如下：

步驟01：如圖，選擇需要輸入身份證号碼的區域D2:D9。

步驟02：選擇“數據”選項卡，在“數據工具”分組中，找到“數據驗證”下拉菜單，單擊“數據驗證”。在“數據驗證”對話框“設置”選項卡下，設置“驗證條件”，在“允許”下拉菜單中選擇“自定義”，在“公式”編輯框中輸入如下公式：

=AND(ISTEXT(D2),LEN(D2)=18,ISNUMBER(--LEFT(D2,17)),OR(ISNUMBER(--RIGHT(D2,1)),EXACT(RIGHT(D2,1,"X")))

為了便于大家理解，下面将各段公式作以說明：

ISTEXT(D2):判斷D2單元格是否為文本，

且

LEN(D2)=18:判斷D2單元格字符個數是否為18個,

且

ISNUMBER(--LEFT(D2,17))：判斷D2單元格前17位是否為數值，

且

OR(ISNUMBER(--RIGHT(D2,1)),EXACT(RIGHT(D2,1),"X"))：判斷D2單元格第18位是否為數值或者是字符"X"。

以上條件都滿足，将返回TRUE，允許輸入内容，否則将彈出錯誤。

注意：

--LEFT(D2,17)和--RIGHT(D2,1)前面的兩個減号的目的是進行減負運算，将字符串轉換為數值，如果是非數字将返回" #VALUE! "錯誤值。

數據驗證對話框

步驟03：單擊“确定”按鈕後，進行驗證。

Excel中的ISEVEN和ISODD可以判斷數字為偶數還是奇數。身份證号碼中的第17位可以判斷性别，如果為奇數則為男性，偶數為女性。

使用如下公式即可判斷：

=IF(ISEVEN(MID(D2,17,1),"女","男")

或者：

=IF(ISODD(MID(D2,17,1)),"男","女")

得到結果如下：

判斷男女

也可以使用MOD函數，根據能否被2整除，可以判斷是否為偶數的原理進行性别判斷。公式如下：

=IF(MOD(MID(D2,17,1),2)=0,"女","男")